Golb Slexa ::

Manche Probleme schafft sich der Mensch ja selbst. So kann ich mit Magix Musikmaker 5.1-Musik erstellen, aber ein Export nach Mp3 erzeugt konsequent lediglich Stereo-Dateien. Wahrscheinlich, weil kein Mp3-Pro-Encoder dem Programm beiliegt - aber eine Fehlermeldung kommt auch nicht.

Es bleibt der Export nach WAV oder Windows Media, um 6 Kanäle zu behalten.
4:43 min Musik erzeugen eine 143 MB grosse WAV-Datei. Und Windows Media … das passt mir grad nicht ;-)

Nun hab ich also meine 5.1 Wave-Datei. Klingt zwar gut, ist aber noch ein klitzekleinwenig zu gross.

Meine Konvertierungsversuche mit VLC oder ffmpeg scheiterten kläglich. Ffmpeg weigerte sich, ein Audio mit mehr als 2 Audiokanälen zu lesen. Beim Export mit VLC erhielt ich grausame akustische Resultate - warum auch immer - soviel liess sich ja auch gar nicht einstellen.

Ich fand aber das Kommandozeilentool Aften - ein simpler Aufruf

aften %infile% %outfile%

… und schon hab ich nach nach ein paar Sekunden meine AC3 Audiodatei von 15 MB:

Aften: A/52 audio encoder
Version 0.0.8
(c) 2006-2007 Justin Ruggles, Prakash Punnoor, et al.

input format: WAVE Signed 16-bit little-endian 44100 Hz 5.1-channel
output format: 44100 Hz 3/2 + LFE

SIMD usage: MMX SSE SSE2 SSE3
Threads: 4

progress: 100% | q: 242.9 | bw: 39.0 | bitrate: 448.0 kbps

Das geht ja einfach! … wenn man das Tool gefunden hat.

Dann machen wir noch eine kleine Batchdatei, auf die man per Drag and drop eine oder mehrere WAV-Dateien ziehen kann und die mir dann AC3s erzeugt (erzeugte Datei im selben Ort, wie WAV mit angehängtem “.ac3”).
Nachfolgend der Code der Batch-Datei. Von dieser Batchdatei eine Verknüpfung auf den Desktop legen. Auf das Desktop-Icon kann die WAV-Datei gezogen werden.

@echo off
rem ======================================================================
::
::  Convert WAV TO AC3 with drag and drop
::  using AFTEN
::
::  2010-09-05  v1.0 www.axel-hahn.de
rem ======================================================================

rem ----------------------------------------------------------------------
:: config
rem ----------------------------------------------------------------------
	rem You need to download Aften and correct its path here:
	set AFTEN="d:/Apps/media/aften-0.0.8-win32-bin/aften.exe"

rem ----------------------------------------------------------------------
:: main
rem ----------------------------------------------------------------------
	echo.
	echo ===== CONVERT WAV TO AC3 =====
	echo.

	if "%1"=="" (
		echo Drag and Drop a file here to convert it. Press a key to exit.
		pause >nul
		exit
	)

	:loop
	echo --- %~1
	call :convert "%~1"
	shift
	if "%1"=="" (
		echo THE END. press a key to exit
		pause >nul
		exit
	)
	goto loop

rem ----------------------------------------------------------------------
:: subs
rem ----------------------------------------------------------------------
	:convert
	set infile="%~1"
	set outfile="%~1.ac3"
	%AFTEN% %infile% %outfile%
	echo output file:
	dir %outfile% | findstr "^[0-9]"
	echo -------------------------------------------------------------------------------

Weiterführende Links

• Aften-Projekt-Seite auf Sourceforge
• Export und Encoding meiner Songs
• Magix Music Maker